Add files via upload

arm/raspi_args.gn

@@ -0,0 +1,65 @@
+google_api_key = ""
+google_default_client_id = ""
+google_default_client_secret = ""
+target_os = "linux"
+target_cpu = "arm64"
+use_system_minigbm = false
+use_vc4_minigbm = true
+enable_linux_installer = true
+enable_distro_version_check = false
+enable_stripping = true
+is_official_build = true
+is_debug = false
+dcheck_always_on = false
+exclude_unwind_tables = true
+# enable_debugallocation = false
+enable_iterator_debugging = false
+disable_fieldtrial_testing_config = true
+enable_resource_allowlist_generation = false
+enable_profiling = false
+is_component_build = false
+symbol_level = 0
+enable_nacl = false
+optimize_webui = true
+use_lld = true
+v8_symbol_level = 0
+blink_symbol_level = 0
+enable_precompiled_headers = false
+media_use_ffmpeg = true
+media_use_libvpx = true
+enable_hls_sample_aes = true
+enable_hls_demuxer = true
+enable_ink = false
+enable_discovery = true
+enable_cros_media_app = false
+proprietary_codecs = true
+ffmpeg_branding = "Chrome"
+enable_ffmpeg_video_decoders = true
+is_component_ffmpeg = true
+use_webaudio_ffmpeg = false
+use_webaudio_pffft = true
+# enable_av1_decoder = true
+# enable_dav1d_decoder = true
+use_vaapi = true
+enable_widevine = true
+bundle_widevine_cdm = false
+ignore_missing_widevine_signing_cert = true
+enable_media_drm_storage = true
+enable_media_overlay = true
+enable_hangout_services_extension = true
+rtc_use_h264 = true
+rtc_include_ilbc = true
+rtc_build_with_neon = true
+rtc_build_examples = false
+enable_vr = true
+use_vr_assets_component = true
+enable_platform_hevc = true
+enable_hevc_parser_and_hw_decoder = true
+enable_platform_ac3_eac3_audio = true
+enable_platform_dolby_vision = true
+enable_platform_mpeg_h_audio = true
+enable_mse_mpeg2ts_stream_parser = true
+use_thin_lto = true
+thin_lto_enable_optimizations = true
+chrome_pgo_phase = 2
+pgo_data_path = "/home/alex/chromium/src/chrome/build/pgo_profiles/chrome-linux-main-1651730035-7c2bc9c754f16e0cb15fef8a61ff068912477ab5.profdata"

arm/raspi_arm.gni

@@ -0,0 +1,151 @@
+# Copyright 2022 The Chromium Authors and Alex313031. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+# ONLY FOR RASPBERRY PI 4!!
+# This should go in //chromium/src/config/arm.gni
+
+import("//build/config/v8_target_cpu.gni")
+
+# These are primarily relevant in current_cpu == "arm" contexts, where
+# ARM code is being compiled.  But they can also be relevant in the
+# other contexts when the code will change its behavior based on the
+# cpu it wants to generate code for.
+if (current_cpu == "arm" || v8_current_cpu == "arm") {
+  declare_args() {
+    # Version of the ARM processor when compiling on ARM. Ignored on non-ARM
+    # platforms.
+    arm_version = 8
+
+    # The ARM architecture. This will be a string like "armv6" or "armv7-a".
+    # An empty string means to use the default for the arm_version.
+    arm_arch = "armv8-a"
+
+    # The ARM floating point hardware. This will be a string like "neon" or
+    # "vfpv3". An empty string means to use the default for the arm_version.
+    arm_fpu = ""
+
+    # The ARM variant-specific tuning mode. This will be a string like "armv6"
+    # or "cortex-a15". An empty string means to use the default for the
+    # arm_version.
+    arm_tune = "cortex-a72"
+
+    # Whether to use the neon FPU instruction set or not.
+    arm_use_neon = "true"
+
+    # Whether to enable optional NEON code paths.
+    arm_optionally_use_neon = true
+
+    # Thumb is a reduced instruction set available on some ARM processors that
+    # has increased code density.
+    arm_use_thumb = true
+  }
+
+  if (current_os == "android" || target_os == "android") {
+    arm_float_abi = "softfp"
+  } else {
+    declare_args() {
+      # The ARM floating point mode. This is either the string "hard", "soft",
+      # or "softfp". An empty string means to use the default one for the
+      # arm_version.
+      arm_float_abi = ""
+    }
+  }
+  assert(arm_float_abi == "" || arm_float_abi == "hard" ||
+         arm_float_abi == "soft" || arm_float_abi == "softfp")
+
+  if (arm_use_neon == "") {
+    if (current_os == "linux" && target_cpu != v8_target_cpu) {
+      # Don't use neon on V8 simulator builds as a default.
+      arm_use_neon = false
+    } else {
+      arm_use_neon = true
+    }
+  }
+
+  if (arm_version == 6) {
+    if (arm_arch == "") {
+      # v8 can still with version 6 but only with the armv6k extension.
+      arm_arch = "armv6k"
+    }
+    if (arm_tune != "") {
+      arm_tune = ""
+    }
+    if (arm_float_abi == "") {
+      arm_float_abi = "softfp"
+    }
+    if (arm_fpu == "") {
+      arm_fpu = "vfp"
+    }
+    arm_use_thumb = false
+    arm_use_neon = false
+  } else if (arm_version == 7) {
+    if (arm_arch == "") {
+      arm_arch = "armv7-a"
+    }
+    if (arm_tune == "") {
+      arm_tune = "generic-armv7-a"
+    }
+
+    if (arm_float_abi == "") {
+      if (current_os == "linux" && target_cpu != v8_target_cpu) {
+        # Default to the same as Android for V8 simulator builds.
+        arm_float_abi = "softfp"
+      } else {
+        arm_float_abi = "hard"
+      }
+    }
+
+    if (arm_fpu == "") {
+      if (arm_use_neon) {
+        arm_fpu = "neon"
+      } else {
+        arm_fpu = "vfpv3-d16"
+      }
+    }
+  } else if (arm_version == 8) {
+    if (arm_arch == "") {
+      arm_arch = "armv8-a"
+    }
+    if (arm_tune == "") {
+      arm_tune = "generic-armv8-a"
+    }
+
+    if (arm_float_abi == "") {
+      arm_float_abi = "hard"
+    }
+
+    if (arm_fpu == "") {
+      if (arm_use_neon) {
+        arm_fpu = "neon"
+      } else {
+        arm_fpu = "vfpv3-d16"
+      }
+    }
+  }
+} else if (current_cpu == "arm64" || v8_current_cpu == "arm64") {
+  # arm64 supports only "hard".
+  arm_float_abi = "hard"
+  arm_use_neon = true
+  declare_args() {
+    # Enables the new Armv8 branch protection features. Valid strings are:
+    # - "pac": Enables Pointer Authentication Code (PAC, featured in Armv8.3)
+    # - "standard": Enables both PAC and Branch Target Identification (Armv8.5).
+    # - "none": No branch protection.
+    arm_control_flow_integrity = "standard"
+
+    # TODO(cavalcantii): enable the feature for the following OSes next.
+    if (is_mac || is_chromeos || is_fuchsia || is_win ||
+        target_cpu != "arm64") {
+      # target_cpu != "arm64" covers some cases (e.g. the ChromeOS x64 MSAN
+      # build) where the target platform is x64, but V8 is configured to use
+      # the arm64 simulator. Pointer authentication doesn't work properly
+      # in this mode (yet).
+      arm_control_flow_integrity = "none"
+    }
+  }
+  assert(arm_control_flow_integrity == "none" ||
+             arm_control_flow_integrity == "standard" ||
+             arm_control_flow_integrity == "pac",
+         "Invalid branch protection option")
+}